#!/usr/bin/perl
#
# by Thomas A. Alspaugh
#
# Licensed under a Creative Commons Attribution-NonCommercial-ShareAlike 2.5 License
# http://creativecommons.org/licenses/by-nc-sa/2.5/
#

use strict;
use warnings;

#  ¤  circle with tabs
#  °
#  ·
#  •

sub help {
  my $cmdname = $0;
  $cmdname =~ s:.*/::;
  print "$cmdname - Produce a formatted HTML presentation of bibtex entries.\n";
  print "The entries are read from .bib files named on the command line, or from\n";
  print "bib files whose keys are named in <dt>, <li>, or <p> elements in a file\n";
  print "given in the -filter option.  -- represents the standard input.\n";
  print "";
  print "Each entry is assumed to have each field on a single line.\n";
  print "";
  print "Annotations may be read from .tex files (-annotation), or linked to in\n";
  print "KEY.notes.html files (-notes).\n";
  print "";
  print "Output for each entry is formatted as a <dt> element of a <dl> list\n";
  print "(default), an <li> element of an <ol> or <ul> list, or a <p> element.\n";
  print "Unless -wrap is given, the output contains only these elements;  you\n";
  print "provide the rest of the HTML.\n";
  print "Output is the formatted bib entry (default);  or an index to key files\n";
  print "(-index);  or an author cross-reference to key files (-authorIndex);\n";
  print "or individual key files (-toKeyFile).\n";
  print " -dt           Make a  <dt id='KEY'>KEY for each entry [DEFAULT].\n";
  print " -li           Make an <li id='KEY'>KEY for each entry.\n";
  print " -p            Make a  <p  id='KEY'>KEY for each entry.\n";
  print " -wrap         Wrap the output with a minimal HTML head and tail.\n";
  print " -abstract     Include abstracts in the HTML output.\n";
  print " -annotation   Include annotations (KEY.tex files) in the HTML output.\n";
  print " -keywords     Include keywords in the HTML output.\n";
  print " -notes=NDIR   Include links to KEY.notes.html files in NDIR [default '.'].\n";
  print " -annotationMark[=MARK]  Mark entries that have an annotation.\n";
  print " -pdfMark[=MARK]  Mark entries that have a pdf file.\n";
  print " -pdfDir=PDIR  Look for pdf files in PDIR [default '.'].\n";
  print " -initials     Assume entries are alphabetized and insert 'initials'.\n";
  print " -filter=FILE  Read from FILE and look for keys to expand.\n";
  print "      Any of the following are expanded with bib information for KEY:\n";
  print "        <dt class=\"bib\">KEY\n";
  print "        <li class=\"bib\">KEY\n";
  print "        <p class=\"bib\">KEY\n";
  print "      Each elements must be an entire line and exactly as above.\n";
  print "      An id=\"KEY\" attribute is added to each element.\n";
  print "      In addition, if the -linkTo option was given, strings of the form\n";
  print "      <a class=\"bib\">KEY</a> are made into a (plain black) link to KEY\n";
  print "      in the bib file (BFILE#KEY).\n";
  print " -linkTo=BFILE  Use BFILE as the bib file name if needed.\n";
  print " -toKeyFile=KFDIR  Write output from each bib file D/KEY.bib to KFDIR/KEY.html.\n";
  print " -keyFileDir=KFDIR  Use KFDIR as the key file directory.\n";
  print " -index=IFILE  Write an index file IFILE with a link to each key file in KFDIR.\n";
  print "      If IFILE is not given, write to standard output.\n";
  print " -css=CNAME or +CNAME  Use CNAME as the style file.\n";
  print "      Create if + is given.  If CNAME is absent, default is DIR.css.\n";
  print " -authorIndex=AFILE  Write an author index to AFILE.\n";
  print "      If AFILE is not given, write to standard output.\n";
}

if ($#ARGV < 0) {
  &help;
  exit 0;
}

my $abstractsIn="";
my $annotationMark="";
my $annotationsIn="";
my $authorIndexFname = "";
my $cssFname = "";
my $cssWrite = "";
my $htmlList = "dl";
my $htmlMark="";
my $htmlTag  = "dt";
my $htmlTag1 = "dd";
my $id = "";
my $indexFname = "";
my $keyFileDir = "";
my $keywordsIn="";
my $linkTo="";
my $makeAuthorIndex = "";
my $makeIndex = "";
my $marks = "";
my $pdfDir = ".";
my $pdfMark="";
my $printEntries = "yes";
my $titleLimit = 80;
my $toKeyFile = "";
my $wrap = "";

my $arg;
my $bibFileName = "";
my $count = 0;
my $fromStdin = "";
my $initialPv=" ";
my $initials = "";
my $aLineNo="";
my $bLineNo="";
my $fLineNo="";
my %args = ();
my %authorIndex = ();
my %authorIndexCounts = ();
my %authorName = ();
my %keys = ();
my $summarize = "";
my %yearCounts = ();

my $entryAlreadyPrinted = "";
my $entryType="";
my $key = "";
my $URL="";
my $abstract="";
my $address="";
my $annotation="";
my $author="";  my $author0="";
my $booktitle="";
my $doi="";
my $editor="";
my $howpublished="";
my $institution="";
my $journal="";
my $keywords="";
my $month="";
my $note="";
my $number="";
my $organization="";
my $pages="";
my $publisher="";
my $school="";
my $title="";
my $type="";
my $volume="";
my $year="";

my $notesDir="";
my $notesFname="";
my $notesIn="";

foreach $arg (@ARGV) {
  # printf STDERR "<$arg>\n";

  if ($arg =~ /^-/) {
    if    ($arg eq "--") {
      $bibFileName = $arg;
      &handleBibFile(\*STDOUT, $cssFname);
    }
    elsif ($arg =~ /^-+help$/) {
      &help;
      exit 0;
    }
    elsif ($arg =~ /^-+abstract$/) {
      $abstractsIn = "yes";
    }
    elsif ($arg =~ /^-+annotation$/) {
      $annotationsIn = "yes";
    }
    elsif ($arg =~ /^-+annotationMark/) {
      if ($arg  =~ /^-+annotationMark=(.+)/) {
        $arg   =~ s/^-+annotationMark=(.+)/$1/;
        $annotationMark = $arg;
      }
      else {
        $annotationMark = "&curren;";
      }
    }
    elsif ($arg =~ /^-+authorIndex(=.+)?$/) {
      $makeAuthorIndex = "yes";
      $printEntries = "";
      if ($arg =~  /^-+authorIndex=(.*)$/) {
          $arg =~ s/^-+authorIndex=(.*)$/$1/;
        $authorIndexFname = $arg;
      }
    }
    elsif ($arg =~  /^-+css=/) {  $cssFname = $arg;
      $cssFname =~ s/^-+css=\+?//;
      if (!$cssFname) {
        if (!$keyFileDir) {
          die "-css= without CNAME must be preceded by -toKeyFile=DIR.\n";
        }
        $cssFname = "$keyFileDir.css";
      }
      # print STDERR "CSS file name \"$cssFname\".\n";
      if ($arg  =~  /^-+css=\+/) {
        $cssWrite = "yes";
      }
    }
    elsif ($arg =~ /^-+dt$/) {
      $htmlList = "dl";
      $htmlTag  = "dt";
      $htmlTag1 = "dd";
    }
    elsif ($arg =~ /^-+filter=/) {
      $arg =~     s/^-+filter=//;
      if ($wrap) {
        print STDERR "Can't give both -wrap and -filter.\n";
      }
      $fLineNo = 0;
      if    ($arg eq "--") {
        $fromStdin = "yes";
        while (<STDIN>) {
          chomp;
          ++$fLineNo;
          &filterLine;
        }
        $fromStdin = "";
      }
      elsif (open FFILE, "<$arg") {
        while (<FFILE>) {
          chomp;
          ++$fLineNo;
          &filterLine;
        }
        close FFILE;
      }
      else {
        print STDERR "Can't open file to filter '$arg'.\n";
        exit -1;
      }
    }
    elsif ($arg =~ /^-+index(=.+)?/) {
      $makeIndex = "yes";
      $printEntries = "";
      if ($arg =~  /^-+index=(.+)/) {
          $arg =~ s/^-+index=(.+)/$1/;
        $indexFname = $arg;
      }
    }
    elsif ($arg =~ /^-+initials$/) {
      $initials = "yes";
      $summarize = "yes";
    }
    elsif ($arg   =~  /^-+keyFileDir=(.+)/) {
      $keyFileDir = $arg;
      $keyFileDir =~ s/^-+keyFileDir=(.+)/$1/;
    }
    elsif ($arg =~ /^-+keywords$/) {
      $keywordsIn = "yes";
    }
    elsif ($arg =~ /^-+li$/) {
      $htmlList = "ul";
      $htmlTag  = "li";
      $htmlTag1 = "p";
    }
    elsif ($arg =~ /^-+linkTo=/) {  $linkTo = $arg;
      $linkTo  =~ s/^-+linkTo=//;
    }
    elsif ($arg =~ /^-+notes$/) {
      $notesIn = "y";
      $notesDir = ".";
    }
    elsif ($arg =~ /^-+notes=(.+)/) {
      $notesIn = "y";
      $arg     =~ s/^-+notes=(.+)/$1/;
      $notesDir = $arg;
    }
    elsif ($arg =~ /^-+p$/) {
      $htmlList = "";
      $htmlTag  = "p";
      $htmlTag1 = "p";
    }
    elsif ($arg =~ /^-+pdfDir=(.+)/) {
      $arg     =~ s/^-+pdfDir=(.+)/$1/;
      $pdfDir = $arg;
    }
    elsif ($arg =~ /^-+pdfMark/) {
      if ($arg  =~ /^-+pdfMark=(.+)/) {
        $arg   =~ s/^-+pdfMark=(.+)/$1/;
        $pdfMark  = $arg;
        $htmlMark = $arg;
      }
      else {
        $pdfMark = "&bull;";
        $htmlMark = "&deg;";
      }
    }
    elsif ($arg =~ /^-+toKeyFile=/) {
      $toKeyFile = "y";
      $printEntries = "";
      $keyFileDir = $arg;
      $keyFileDir =~ s/^-+toKeyFile=(.+)/$1/;
    }
    elsif ($arg =~ /^-+wrap$/) {
      $wrap = "y";
    }
    else {
      print STDERR "Unknown option $arg.\n";
      exit -1;
    }
  }
  elsif ($arg =~ /\.bib$/) {
    $args{uc $arg} = $arg;
  }
  else {
    print STDERR "Not a .bib file:  $arg\n";
    exit;
  }
}

if ($toKeyFile && $keyFileDir =~ /\//) {
  die "If writing to key files, key file directory must not contain '/'.\n";
}
if ($keyFileDir =~ /\.\.?/) {
  die "Key file directory must not be '.' or '..'.\n";
}
if ($makeAuthorIndex && !$keyFileDir) {
  die "-authorIndex requires -keyFileDir.\n";
}
if ($toKeyFile && $keyFileDir && ! -d $keyFileDir) {
  print STDERR "Making key file directory '$keyFileDir' with mode 0755.\n";
  if (!mkdir $keyFileDir, 0755) {
    die "Can't make -keyFileDir directory '$keyFileDir'.\n";
  }
}

my $HINDEX;
if ($makeIndex) {
  if ($indexFname) {
    if (!open $HINDEX, ">$indexFname") {
      die "Can't open index output file '$indexFname'.\n";
    }
  }
  else {
    $HINDEX = \*STDOUT;
  }
  #print STDERR "### 309\n";
  &wrapHead($HINDEX,  $cssFname, $initials, "Papers index");
  print $HINDEX "<!-- index -->\n";
}

my $HAINDEX;
if ($makeAuthorIndex) {
  if ($authorIndexFname) {
    if (!open $HAINDEX, ">$authorIndexFname") {
      die "Can't open author index output file '$authorIndexFname'.\n";
    }
  }
  else {
    $HAINDEX = \*STDOUT;
  }
  #print STDERR "### 324\n";
  &wrapHead($HAINDEX, $cssFname, $initials, "Author Index");
  print $HAINDEX "<!-- author index -->\n";
}

if ($printEntries && $wrap)    {
  #print STDERR "### 330\n";
  &wrapHead(\*STDOUT,  $cssFname, $initials, "Papers index");
}
if ($cssWrite)        {  &writeCss;  }

my @ucArgs;
my $ucArg;

if (%args) {
  @ucArgs = sort keys %args;
  if ($toKeyFile) {
    foreach $ucArg (@ucArgs) {
      $bibFileName = $args{$ucArg};
      $key = $bibFileName;
      $key =~ s/\.bib$//;
      $key =~ s/^.*\///;
      my $keyFileOut = "$keyFileDir/$key.html";
      my $HOUT;
      if (open $HOUT, ">$keyFileOut") {
        print STDERR "Writing $keyFileOut\n";
        if ($cssFname) {
          #print STDERR "### 350\n";
          &wrapHead($HOUT, "../$cssFname", "", "$key");
          if ($cssWrite) {  &writeCss;  }
        }
        else           {
          #print STDERR "### 355\n";
          &wrapHead($HOUT,             "", "", "$key");
        }
        &handleBibFile($HOUT);
        &wrapTail($HOUT);
        close $HOUT;
      }
      else {
        die "Can't open output file \"$keyFileOut\".\n";
      }
    }
  }
  else {
    foreach $ucArg (@ucArgs) {
      $bibFileName = $args{$ucArg};
      &handleBibFile(\*STDOUT);
    }
  }
}

if ($initials && $initialPv ne " " && $htmlList) {
  print STDOUT "</$htmlList>\n\n";
}

if ($makeAuthorIndex) {
  &printAuthorIndex(\*$HAINDEX);
}

if ($summarize) {
  print STDOUT "<p> <i>$count entries.</i>\n";
  if (scalar %yearCounts) {
    print STDOUT "<table style='font-size:.95em'>\n";
    foreach $year (reverse sort keys %yearCounts) {
      my $count = $yearCounts{$year};
      print STDOUT "  <tr><td style='text-align:right'>$year";
      print STDOUT "<td style='font-style:italic;text-align:right;'>$count";
      print STDOUT "<td>";
      my $incr = 2;
      $count += $incr - 1;
      while (0 < $count) {
        print STDOUT "=";
        $count -= $incr;
      }
      print STDOUT "\n";
    }
    print STDOUT "</table>\n";
  }
}

if ($printEntries && $wrap) {  &wrapTail(\*STDOUT );  }
if ($makeAuthorIndex)       {  &wrapTail(\*$HAINDEX);   }
if ($makeIndex)             {  &wrapTail(\*$HINDEX );  }

if ($indexFname)       {  close $HINDEX;   }
if ($authorIndexFname) {  close $HAINDEX;  }

# - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -


#
#  Handle the -filter option for $_ and print the result.
#
sub filterLine {
  if    (/<(dt|li|p) class=('bib'|"bib")> *([a-zA-Z]+((\+[a-zA-Z]+){0,3}|\+[a-zA-Z]+\+)[0-9]{4}-[a-z0-9]{1,4}(-[a-z]+)?)/) {
    #print;
      s/.*<(dt|li|p) class=('bib'|"bib")> *([a-zA-Z]+((\+[a-zA-Z]+){0,3}|\+[a-zA-Z]+\+)[0-9]{4}-[a-z0-9]{1,4}(-[a-z]+)?).*/$3/;
    if ($keyFileDir) {  $bibFileName = "$keyFileDir/$_.bib";  }
    else             {  $bibFileName = "$_.bib";  }
    print "\n";
    &handleBibFile(\*STDOUT, "");
    print "\n";
  }
  elsif (/<(a) class=('bib'|"bib")>([a-zA-Z]+((\+[a-zA-Z]+){0,3}|\+[a-zA-Z]+\+)[0-9]{4}-[a-z0-9]{1,4})<\/a>/) {
        s/<(a) class=('bib'|"bib")>([a-zA-Z]+((\+[a-zA-Z]+){0,3}|\+[a-zA-Z]+\+)[0-9]{4}-[a-z0-9]{1,4})<\/a>/<a class='bib' href='$linkTo#$3'>$3<\/a>/g;
    s/(<a class='bib' href='.+?#[^'+]+)\+/$1_/g;
    s/(<a class='bib' href='.+?#[^'+]+)\+/$1_/g;
    s/(<a class='bib' href='.+?#[^'+]+)\+/$1_/g;
    print "$_\n";
  }
  else {
    # print STDERR "###  nonfiltered line\n";
    print "$_\n";
  }
}


#
# Fix all the things that can be wrong with $_.
#
sub fixline {
  chomp;

  s/\\\\/\\##/g;
  s/\\ensuremath\{([^}]+)}/\$$1\$/g;
  s/\\?&/&amp;/g;   # must precede anything with an ampersand
  s/</&lt;/g;
  s/>/&gt;/g;
  s/\\_/_/g;
  s/\\(exist)s/&$1;/g;
  s/\\(forall)/&$1;/g;
  s/\\Rightarrow/&rArr;/g;
  s/\\diamond/&loz;/g;
  s/\\box/ BOX /g;
  s/\\texttrademark/&trade;/g;
  s/{\\'(.)}/&$1acute;/g;
  s/{\\`(.)}/&$1grave;/g;
  s/{\\"(.)}/&$1uml;/g;
  s/{\\~(.)}/&$1tilde;/g;
  s/{\\c(.)}/&$1cedil;/g;
  s/{\\AA}/&Aring;/g;
  s/{\\ae}/&aelig;/g;
  s/{\\o}/&oslash;/g;
  s/{\\O}/&Oslash;/g;
  s/\$\\([Aa]lpha)\$/&$1;/g;
  s/\$\\([Bb]eta)\$/&$1;/g;
  s/\$\\([Gg]amma)\$/&$1;/g;
  s/\$\\([Dd]elta)\$/&$1;/g;
  s/\$\\([Ee]psilon)\$/&$1;/g;
  s/\$\\([Zz]eta)\$/&$1;/g;
  s/\$\\([Ee]ta)\$/&$1;/g;
  s/\$\\([Tt]heta)\$/&$1;/g;
  s/\$\\([Ii]ota)\$/&$1;/g;
  s/\$\\([Kk]appa)\$/&$1;/g;
  s/\$\\([Ll]ambda)\$/&$1;/g;
  s/\$\\([Mm]u)\$/&$1;/g;
  s/\$\\([Nn]u)\$/&$1;/g;
  s/\$\\([Xx]i)\$/&$1;/g;
  s/\$\\([Oo]micron)\$/&$1;/g;
  s/\$\\([Pp]i)\$/&$1;/g;
  s/\$\\([Rr]ho)\$/&$1;/g;
  s/\$\\([Ss]igma)\$/&$1;/g;
  s/\$\\([Tt]au)\$/&$1;/g;
  s/\$\\([Uu]psilon)\$/&$1;/g;
  s/\$\\([Pp]hi)\$/&$1;/g;
  s/\$\\([Cc]hi)\$/&$1;/g;
  s/\$\\([Pp]si)\$/&$1;/g;
  s/\$\\([Oo]mega)\$/&$1;/g;
  s/\\emph{([^}]*)}/<i>$1<\/i>/g;
  s/\\textit{([^}]*)}/<i>$1<\/i>/g;
  s/\\textsf{([^}]*)}/$1/g;      # Unable to put class="sf" in the to string.
  s/\\begin\{description\}/<dl>/g;
  s/\\begin\{enumerate\}/<ol>/g;
  s/\\begin\{itemize\}/<ul>/g;
  s/\\begin\{quote\}/<blockquote>/g;
  s/\\begin\{quotation\}/<blockquote>/g;
  s/\\item *\[([^]]+)\]/<dt>$1<dd>/g;
  s/\\item/<li>/g;
  s/\\end\{description\}/<\/dl>/g;
  s/\\end\{enumerate\}/<\/ol>/g;
  s/\\end\{itemize\}/<\/ul>/g;
  s/\\end\{quote\}/<\/blockquote>/g;
  s/\\end\{quotation\}/<\/blockquote>/g;
  s/---/&mdash;/g;
  s/--/-/g;
  s/``/&ldquo;/g;
  s/''/&rdquo;/g;
  #s/~/&nbsp;/g;
  s/\\neg/&not;/g;
  s/\\ne/&ne;/g;
  s/\^([^\$]+)\$/<sup>$1<\/sup>/g;
  s/_([^\$]+)\$/<sub>$1<\/sub>/g;
  s/\$//g;
  s/\\url{([^}]+)}/<span class="URL">$1<\/span>/;
  s/\\##/\\/g;   # To undo the hack done up above to handle escaped \ correctly.

  s/[{}]//g;

  # Bad characters
  if    (/Ñ/) {
    printf STDERR "Bad character (1) 'Ñ' ('---') in $bibFileName:  $_\n";
  }
  if    (/À/) {
    printf STDERR "Bad character (2) 'À' ('---') in $bibFileName:  $_\n";
  }
  # if    (/- /) {
    # printf STDERR "Possibly undesired hyphen ('- ') in $bibFileName:  $_\n";
  # }
}


#
#  Handle a bibfile whose name is in $bibFileName.
#
sub handleBibFile {   # ($HOUT)
  my $HOUT = $_[0];
  ++$count;
  $bLineNo = 0;
  if    ($bibFileName eq "--") {
    $fromStdin = "yes";
    while (<STDIN>) {
      ++$bLineNo;
      &parseBibFileLine($HOUT);
    }
    if ($entryType) {
      &printBibFileEntry($HOUT);
    }
    $fromStdin = "";
  }
  elsif (open BFILE, "<$bibFileName") {
    while (<BFILE>) {
      ++$bLineNo;
      &parseBibFileLine($HOUT);
    }
    if ($entryType) {
      if ($printEntries || $toKeyFile) {
        &printBibFileEntry($HOUT);
      }
      if ($makeIndex) {
        &printIndexEntry;
      }
      if ($makeAuthorIndex) {
        &indexEntryAuthors;
      }
    }
    close BFILE;
  }
  else {
    if ($fLineNo) {
      print STDERR "(line $fLineNo)  ";
    }
    print STDERR "Can't open input file $bibFileName\n";
    exit -1;
  }
  $bibFileName = "--";
}


#
#  Add the current entry's authors to the author index.
#  The index entries are the keys, separated by '  '.
#
sub indexEntryAuthors {
  #print STDERR "### indexEntryAuthors '$author0'\n";
  if ($author0) {
    my $tmp = " and $author0";
    while ($tmp =~ / and /) {
      my $a = $tmp;
      $tmp =~ s/(.*) and (.+)/$1/;
      $a   =~ s/(.*) and (.+)/$2/;
      $_ = $a;
      my $a0 = $a;
      $a =~ s/&(.)[^;]+;/$1/g;
      if (! exists $authorName{$a}) {
        $authorName{$a} = $a0;
      }
      #print STDERR "### -   indexEntryAuthors '$a' ('$a0')\n";
      my $ai = " ";
      if (exists $authorIndex{$a}) {
        #print STDERR "###  =  indexEntryAuthors '$a'\n";
        $ai = $authorIndex{$a};
      }
      else {
        #print STDERR "###  +  indexEntryAuthors '$a'\n";
      }
      #
      $ai   = "$ai      <a href='$keyFileDir\/$key.html' class='indexA'>$key<\/a>\n";
      if ($title) {
        my $trimmedTitle = $title;
        if (length $title > $titleLimit) {
          $trimmedTitle = substr ($title, 0, $titleLimit) . " ...";
        }
        $ai = "$ai      <span class='indexTitle'>$trimmedTitle</span>\n";
      }
      $ai   = "$ai      <br>\n";
      #
      $authorIndex{$a} = $ai;
      $count = $authorIndexCounts{$a};
      ++$count;
      $authorIndexCounts{$a} = $count;
      #print STDERR "###  +  indexEntryAuthors '$a' -> '$ai'\n";
    }
    if ($tmp) {
      die "Unexpected author residue '$tmp' for '$key'.\n";
    }
  }
}


#
#  Classify and optionally store data from a line of a bib file.
#
sub parseBibFileLine {   # ($HOUT)
  my $HOUT = $_[0];
  &fixline;
  if    (/^@/) {
#    if ($entryType && !$entryAlreadyPrinted) {
#      &printBibFileEntry($HOUT);
#    }
    $entryAlreadyPrinted = "";
    $entryType = $_;  $entryType =~ s/^@(.*)\(.*/$1/;
    $key  = $_;  $key  =~ s/.*\((.*),/$1/;
    #
    $URL="";
    $abstract="";
    $address="";
    $annotation="";
    $author="";  $author0 = "";
    $booktitle="";
    $doi="";
    $editor="";
    $howpublished="";
    $institution="";
    $journal="";
    $keywords="";
    $month="";
    $note="";
    $number="";
    $organization="";
    $pages="";
    $publisher="";
    $school="";
    $title="";
    $type="";
    $volume="";
    $year="";
    #
    $notesFname = "";
  }
  elsif (/^ISBN=/)        {}
  elsif (/^LCCN=/)        {}
  elsif (/^URL=/)         {  s/ *[a-zA-Z]+ *=(.*),/$1/;  $URL          = $_;  }
  elsif (/^abstract/)     {  s/ *[a-zA-Z]+ *=(.*),/$1/;  $abstract     = $_;  }
  elsif (/^address=/)     {  s/ *[a-zA-Z]+ *=(.*),/$1/;  $address      = $_;  }
  elsif (/^annotated=/)   {}
  elsif (/^annotation=/)  {  s/ *[a-zA-Z]+ *=(.*),/$1/;  $annotation   = $_;  }
  elsif (/^annote=/)      {}
  elsif (/^author/)       {  s/ *[a-zA-Z]+ *=(.*),/$1/;  $author       = $_;
    $author0 = $author;
    #print STDERR "### -    '$author'\n";
    $author =~ s/ and /#/g;
    #print STDERR "###  -   '$author'\n";
    $author =~ s/^(.+)/#$1#/;
    #print STDERR "###   -  '$author'\n";
    while ($author =~  /#([^#]+)#/) {
      if  ($author =~  /#([^#]+), ([^#,]+)#/) {
        $author    =~ s/#([^#]+), ([^#,]+)#/%$2 $1#/;
      }
      else {
        $author    =~ s/#([^#]+)#/%$1#/;
      }
      #print STDERR "###    - '$author'\n";
    }
    $author =~ s/^%//;
    if    ($author =~  /(%.+)%([^%]+)#$/) {  #print STDERR "###1 '$author'\n";
           $author =~ s/(%.+)%([^%]+)#$/$1, and $2/;
           $author =~ s/%/, /g;
    }
    elsif ($author =~  /%([^%]+)#$/) {       #print STDERR "###2 '$author'\n";
           $author =~ s/%([^%]+)#/ and $1/;
    }
    else {                                   #print STDERR "###3 '$author'\n";
      $author =~ s/^#//;
      $author =~  s/#$//;
    }
  }
  elsif (/^bibchecked=/)  {}
  elsif (/^bibcreated=/)  {}
  elsif (/^bibcreated=/)  {}
  elsif (/^booktitle/)    {  s/ *[a-zA-Z]+ *=(.*),/$1/;  $booktitle    = $_;  }
  elsif (/^chapter=/)     {}
  elsif (/^day=/)         {}
  elsif (/^doi=/)         {  s/ *[a-zA-Z]+ *=(.*),/$1/;  $doi          = $_;  }
  elsif (/^edition=/)     {}
  elsif (/^editor/)       {  s/ *[a-zA-Z]+ *=(.*),/$1/;  $editor       = $_;  }
  elsif (/^editor=/)      {}
  elsif (/^howpublished/) {  s/ *[a-zA-Z]+ *=(.*),/$1/;  $howpublished = $_;  }
  elsif (/^institution/)  {  s/ *[a-zA-Z]+ *=(.*),/$1/;  $institution  = $_;  }
  elsif (/^journal/)      {  s/ *[a-zA-Z]+ *=(.*),/$1/;  $journal      = $_;  }
  elsif (/^key=/) {}
  elsif (/^keywords=/)    {  s/ *[a-zA-Z]+ *=(.*),/$1/;  $keywords     = $_;  }
  elsif (/^location=/)    {}
  elsif (/^misc=/)        {}
  elsif (/^month/)        {  s/ *[a-zA-Z]+ *=(.*),/$1/;  $month        = $_;  }
  elsif (/^note=/)        {  s/ *[a-zA-Z]+ *=(.*),/$1/;  $note         = $_;  }
  elsif (/^number/)       {  s/ *[a-zA-Z]+ *=(.*),/$1/;  $number       = $_;  }
  elsif (/^organization/) {  s/ *[a-zA-Z]+ *=(.*),/$1/;  $organization = $_;  }
  elsif (/^pages/)        {  s/ *[a-zA-Z]+ *=(.*),/$1/;  $pages        = $_;  }
  elsif (/^publisher/)    {  s/ *[a-zA-Z]+ *=(.*),/$1/;  $publisher    = $_;  }
  elsif (/^references=/)  {}
  elsif (/^school/)       {  s/ *[a-zA-Z]+ *=(.*),/$1/;  $school       = $_;  }
  elsif (/^series=/)      {}
  elsif (/^title/)        {  s/ *[a-zA-Z]+ *=(.*),/$1/;  $title        = $_;  }
  elsif (/^type/)         {  s/ *[a-zA-Z]+ *=(.*),/$1/;  $type         = $_;  }
  elsif (/^volume/)       {  s/ *[a-zA-Z]+ *=(.*),/$1/;  $volume       = $_;  }
  elsif (/^year/)         {  s/ *[a-zA-Z]+ *=(.*),/$1/;  $year         = $_;  }
  #
  elsif (/^\)/) {}
  elsif (/^$/) {}
  #
  else {
    if ($bLineNo) {
      print STDERR "(line $bLineNo)  ";
    }
    print STDERR "Unexpected field type \"$_\" for $bibFileName.\n";
  }
}


#
#  Print the author index
#
sub printAuthorIndex {  # ($HOUT)
  #print STDERR "### printAuthorIndex ". (scalar keys %authorIndex) . "\n";
  my $HOUT = $_[0];
  my $a;
  foreach $a (sort keys %authorIndex) {
    my $line  = $authorIndex{$a};
    my $count = $authorIndexCounts{$a};
    my $a0 = $authorName{$a};
    print $HOUT "  <$htmlTag>$a0 ($count)\n";
    print $HOUT "    <$htmlTag1>\n";
    print $HOUT $line;
  }
}


#
#  Handle an entry whose parts are in the various variables.
#
sub printBibFileEntry {   # ($HOUT)
  my $HOUT = $_[0];
  if (exists $keys{$key}) {
    print STDERR "Duplicated key $key in $keys{$key}, $bibFileName.\n";
  }
  $keys{$key} = $bibFileName;
  #
  if ($year) {
    my $y = $year;
    $y =~ s/-.*//;
    $y =~ s/^([0-9]+) B.C./-$1/;
    my $yearCount;
    if (exists $yearCounts{$y}) {
      $yearCount = 1 + $yearCounts{$y};
    }
    else {
      $yearCount = 1;
    }
    $yearCounts{$y} = $yearCount;
  }
  #
  if ($month =~ /#/) {
    $month =~ s/ # //g;
  }
  if ($month) {
    $month =~ s/\bjan\b/Jan./;
    $month =~ s/\bfeb\b/Feb./;
    $month =~ s/\bmar\b/Mar./;
    $month =~ s/\bapr\b/Apr./;
    $month =~ s/\bmay\b/May/;
    $month =~ s/\bjun\b/June/;
    $month =~ s/\bjul\b/July/;
    $month =~ s/\baug\b/Aug./;
    $month =~ s/\bsep\b/Sep./;
    $month =~ s/\boct\b/Oct./;
    $month =~ s/\bnov\b/Nov./;
    $month =~ s/\bdec\b/Dec./;
  }
  &setMarks;
  if ($abstract) {
    $abstract =~ s/([.:;?!]) ([A-Z])/$1&nbsp; $2/g;
    $abstract =~ s/\\par([ \n])/<p>$1/g;  # for multi-paragraph abstracts
  }
  if ($annotationsIn) {
    my $fileKey = $bibFileName;
    $fileKey =~ s/\.bib$//;
    my $annFile = "$fileKey.tex";
    if (-f $annFile) {
      print STDERR "  Including $annFile\n";
      if (open AFILE, "<$annFile") {
        $aLineNo = 0;
        while (<AFILE>) {
          ++$aLineNo;
          &fixline;
          if ($_ eq "") {
            $_ = "<p>";
          }
          s/%.*//;
          $annotation = "$annotation$_\n";
        }
        close AFILE;
      }
      else {
        die "Can't open \"$annFile\".\n";
      }
    }
    $annotation =~ s/([.:;?!]) ([A-Z])/$1&nbsp; $2/g;
    $annotation =~ s/\\par([ \n])/<p>$1/g;  # for multi-paragraph annotations
  }
  if ($keywords) {
    $keywords =~ s/([.:;?!]) ([A-Z])/$1&nbsp; $2/g;
  }
  if ($note) {
    $note =~ s/([.:;?!]) ([A-Z])/$1&nbsp; $2/g;
  }
  if ($notesIn) {
    $notesFname = "$notesDir/$key.notes.html";
    if (-f "$notesFname") {
      print STDERR "  Linking to $notesFname\n";
    }
    else {
      $notesFname = "";
    }
  }
  #
  if ($initials) {
    my $initial = uc substr($key, 0, 1);
    if ($initial ne $initialPv) {
      if ($initialPv ne " " && $htmlList) {
        print $HOUT "</$htmlList>\n\n";
      }
      print $HOUT "<div id='$initial' class='initial'>$initial</div>\n";
      print $HOUT "<p class='top'>[<a href='#'>top</a>]</p>\n";
      if ($htmlList) {
        print $HOUT "<$htmlList>\n";
      }
      $initialPv = $initial;
    }
  }
  #
  $id = $key;
  $id =~ s/\+/_/g;
  #
  if    ($linkTo && $fromStdin) {
    print $HOUT "<$htmlTag id='$id'><span class='bib'>";
    print $HOUT "<a target='bib' class='black' href='$linkTo#$id'>$key</a>";
    print $HOUT "$marks</span>\n<$htmlTag1>";
  }
  elsif ($toKeyFile) {
    print $HOUT "<$htmlTag id='$id'><span class='bib'>$key</span>\n<$htmlTag1>";
  }
  else {
    print $HOUT "<$htmlTag id='$id'><span class='bib'>$key$marks</span>\n<$htmlTag1>";
  }
  if   ($entryType eq "Article") {
    print $HOUT "$author.&nbsp;\n$title.&nbsp;\n";
    print $HOUT "<i>$journal</i>,";
    if ($volume) {  print $HOUT " <b>$volume</b>";  }
    if ($number) {  print $HOUT "($number)";  }
    if ($pages ) {  print $HOUT ":$pages,";  }
    if ($month ) {  print $HOUT " $month,";  }
    print $HOUT " $year.&nbsp;\n";
  }
  elsif ($entryType eq "Book") {
    if ($author) {  print $HOUT "$author.&nbsp;";  }
    if ($editor) {
      print $HOUT "$editor, editor";
      if ($editor =~ / and /) {  print $HOUT "s";  }
      print $HOUT ".&nbsp; ";
    }
    print $HOUT "<i>$title</i>.&nbsp;\n";
    if ($publisher) {  print $HOUT " $publisher,";  }
    if ($address)   {  print $HOUT " $address,";  }
    print $HOUT " $year.&nbsp;\n";
  }
  elsif ($entryType eq "InBook") {
    print $HOUT "$author.&nbsp;\n$title.&nbsp;\n";
    print $HOUT "In";
    if ($editor) {
      print $HOUT " $editor, editor";
      if ($editor =~ / and /) {  print $HOUT "s";  }
      print $HOUT ", ";
    }
    print $HOUT " <i>$booktitle</i>, pp. $pages.&nbsp;\n";
    if ($publisher) {  print $HOUT "$publisher";  }
    print $HOUT " $year.&nbsp;\n";
  }
  elsif ($entryType eq "InCollection") {
    print $HOUT "$author.&nbsp;\n$title.&nbsp;\n";
    print $HOUT "In";
    if ($editor) {
      print $HOUT " $editor, editor";
      if ($editor =~ / and /) {  print $HOUT "s";  }
      print $HOUT ", ";
    }
    print $HOUT " <i>$booktitle</i>, pp. $pages.&nbsp;\n";
    if ($publisher) {  print $HOUT "$publisher";  }
    print $HOUT " $year.&nbsp;\n";
  }
  elsif ($entryType eq "InProceedings") {
    print $HOUT "$author.&nbsp;\n$title.&nbsp;\n";
    print $HOUT "In";
    if ($editor) {
      print $HOUT " $editor, editor";
      if ($editor =~ / and /) {  print $HOUT "s";  }
      print $HOUT ", ";
    }
    print $HOUT " <i>$booktitle</i>, ";
    if ($pages) {  print $HOUT "pp. $pages.&nbsp;\n";  }
    if ($publisher) {  print $HOUT " $publisher,";  }
    if ($month) {  print $HOUT " $month";  }
    print $HOUT " $year.&nbsp;\n";
  }
  elsif ($entryType eq "Manual") {
    print $HOUT "$title.&nbsp;\n";
    print $HOUT "$organization,\n";
    print $HOUT "$year.&nbsp;\n";
  }
  elsif ($entryType eq "Misc") {
    if ($author)       {  print $HOUT "$author.&nbsp;\n";  }
    if ($title)        {  print $HOUT "$title.&nbsp;\n";  }
    if ($howpublished) {  print $HOUT " $howpublished.&nbsp;";  }
    if ($month)        {  print $HOUT " $month";  }
    if ($year)         {  print $HOUT " $year.&nbsp;\n";  }
    if ($note)         {  print $HOUT " $note.&nbsp;\n";  }
  }
  elsif ($entryType eq "PhDThesis" || $entryType eq "MastersThesis") {
    print $HOUT "$author.&nbsp; <i>$title</i>.&nbsp;\n";
    if ($school) {  print $HOUT "$school ";  }
    if ($month)  {  print $HOUT "$month ";  }
    print $HOUT "$year.&nbsp;\n";
  }
  elsif ($entryType eq "Proceedings") {
    print $HOUT "<i>$booktitle</i>, \n";
    print $HOUT "$year.&nbsp;\n";
  }
  elsif ($entryType eq "TechReport") {
    if ($author) {  print $HOUT "$author.&nbsp;";  }
    print $HOUT "$title.&nbsp;\n";
    if ($type)                    {  print $HOUT "$type";  }
    if ($number)                  {  print $HOUT " $number.&nbsp;";  }
    if ($institution)             {  print $HOUT " $institution";  }
    if ($institution && $address) {  print $HOUT ", ";  }
    if ($address)                 {  print $HOUT "$address";  }
    if ($institution || $address) {  print $HOUT ".&nbsp; ";  }
    if ($month)                   {  print $HOUT " $month";  }
    if ($year)                    {  print $HOUT " $year.&nbsp;\n";  }
    else                          {  print $HOUT ".\n";  }
  }
  else {
    print STDERR "Unexpected entry type \"$type\" for $bibFileName.\n";
  }
  $entryType = "";
  #
  if ($keywords && $keywordsIn) {
    print $HOUT "<div class='keywords'><span class='keywordsHeading'>Keywords:&nbsp;</span>\n";
    print $HOUT "  $keywords\n";
    print $HOUT "</div>\n";
  }
  if ($abstract && $abstractsIn) {
    print $HOUT "<div class='abstract'><span class='abstractHeading'>Abstract:&nbsp;</span>\n";
    print $HOUT "  $abstract\n";
    print $HOUT "</div>\n";
  }
  if ($annotation && $annotationsIn) {
    print $HOUT "<div class='annotation'><span class='annotationHeading'>Annotation:</span>&nbsp;\n";
    #  Each bib key KEY is made into links to that bib entry (if it exists).
    #  If output from .bib files is going to a single file, the link goes to #KEY.
    #  If -toKeyFile was given, the link goes to $keyFileDir/KEY.html.
    #  If -filter was given, this subroutine should not be called.
    if ($toKeyFile) {
      $annotation =~ s/([a-zA-Z]+((\+[a-zA-Z]+){0,3}|\+[a-zA-Z]+\+)[0-9]{4}-[a-z0-9]{1,4})/<a href='$keyFileDir\/$1.html'>$1<\/a>/g;
    }
    else {
      $annotation =~ s/([a-zA-Z]+((\+[a-zA-Z]+){0,3}|\+[a-zA-Z]+\+)[0-9]{4}-[a-z0-9]{1,4})/<a href='\#$1'>$1<\/a>/g;
    }
    $annotation =~ s/(href='#[^'+]+)\+/$1_/g;
    $annotation =~ s/(href='#[^'+]+)\+/$1_/g;
    $annotation =~ s/(href='#[^'+]+)\+/$1_/g;
    print $HOUT "  $annotation\n";
    print $HOUT "</div>\n";
  }
  if ($notesIn && $notesFname) {
    print $HOUT "<div class='notes'>\n";
    print $HOUT "  <a title='notes' href='$notesFname'>Notes</a>\n";
    print $HOUT '</div>';
  }
  if ($doi) {
    if ($doi =~ /^http:/) {}
    else {
      $doi = "http://dx.doi.org/$doi";
    }
    print $HOUT "<div class='doi'>";
    print $HOUT "  <a title='doi' href='$doi'>$doi</a>\n";
    print $HOUT '</div>';
  }
  if ($URL) {
    print $HOUT "<div class='URL'>";
    print $HOUT "  <a title='URL' href='$URL'>$URL</a>\n";
    print $HOUT '</div>';
  }
  print $HOUT "\n";
  $entryType = "";
}


#
#  Write an index entry from the data in the various variables.
#
sub printIndexEntry {
  my $trimmedTitle = $title;
  if (length $title > $titleLimit) {
    $trimmedTitle = substr ($title, 0, $titleLimit) . " ...";
  }
  &setMarks;
  print $HINDEX "<$htmlTag class='index' id='$id'>";
  print $HINDEX "<a href='$keyFileDir/$key.html' class='indexKey'>$key</a>";
  print $HINDEX "$marks";
  print $HINDEX "<a href='$keyFileDir/$key.html' class='indexTitle'>$trimmedTitle</a>";
  print $HINDEX "\n";
}


sub printStyle{   # ($HOUT)
  my $HOUT = $_[0];
  if ($initials) {
    print $HOUT
    "    dt, li, p.index {  margin-left: 2em;  }\n";
  }
  print $HOUT
"
    body   {  font-size: 14px;  }
    dt     {  margin-top: 1.2ex;  margin-bottom:  .1ex;  }
    dd     {  margin-top: 0;    margin-bottom: 1.2ex;  }
    .bib   {  font-style: italic;  font-weight: bold;  }
    .index {
      font-weight: bold;
      font-size: 14px;
      margin-bottom: 0ex;  margin-top: 0ex;
    }
    .indexKey {
      font-weight: bold;
      text-decoration: none;
    }
    .indexMarks, .indexTitle {
      font-weight: normal;
      text-decoration: none;
      color: gray;
      margin-left: .5em;
    }
    .indexA {  text-decoration: none;  }
    .top   {
      font-size: smaller;
      font-style: italic;
      margin: 0;  margin-top: -1em;
      float: right;
    }
    div.initial {
      font-size: 1.5em;
      font-weight: bold;
      margin-top: 1.5em;  margin-bottom: 0;
    }
    span.URL {  font-family: sans-serif;  }
    div.abstract, div.annotation, div.keywords, div.notes  {
      font-size: .95em;
      margin: 1ex 0 1ex 1em;
    }
    span.abstractHeading, span.annotationHeading, span.keywordsHeading {
      font-variant: small-caps;
    }
    div.annotation {
      font-family: sans-serif;
      font-size: .95em;
    }
    div.doi, div.URL {
      font-family: sans-serif;
      font-size: .90em;
      margin: 1ex 0 1ex 0;
    }
    div.notes {
      font-family: sans-serif;
      font-variant: small-caps;
    }
    .ss {  font-family: sans-serif;  }

";
}


#
#  Set up the marks for the current entry.
#
sub setMarks {
  $marks = "";
  if ($pdfMark) {
    if    (-e "$pdfDir/$key.pdf") {  # $key.pdf can be a directory
      $marks = "$marks<a href='$pdfDir/$key.pdf' class='indexA'>$pdfMark</a>";
    }
    elsif (-f "$pdfDir/$key.html") {
      $marks = "$marks<a href='$pdfDir/$key.html' class='indexA'>$htmlMark</a>";
    }
  }
  if ($annotationMark && $annotation) {
    $marks = "$marks$annotationMark";
  }
  if ($marks) {
    $marks = "<span class='indexMarks'>$marks</span>";
  }
}


#
#  Write a CSS file.
#
sub writeCss {
  $cssWrite = "";
  if (open HCSS, ">$cssFname") {
    print STDERR "Writing default CSS file \"$cssFname\".\n";
    &printStyle(\*HCSS);
    close HCSS;
  }
  else {
    die "Can't write CSS style file \"$cssFname\".\n";
  }
}


sub wrapHead {   # ($HOUT, $cssFname, $initials, $title)
  my $HOUT     = $_[0];
  my $cssFname = $_[1];
  my $initials = $_[2];
  my $title    = $_[3];
  print $HOUT "<!DOCTYPE HTML PUBLIC \"-//W3C//DTD HTML 4.01//EN\"
                      \"http://www.w3.org/TR/html4/strict.dtd\">\n";
  print $HOUT "<html>\n";
  print $HOUT "<head>\n";
  if ($title) {
    print $HOUT "  <title>$title</title>\n";
  }
  if ($cssFname) {
    print $HOUT "  <link href='$cssFname' rel='stylesheet' type='text/css'>\n";
  }
  else {
    print $HOUT "  <style type=\"text/css\">\n";
    &printStyle($HOUT);
    print $HOUT "  </style>\n";
  }
  print $HOUT "</head>\n";
  print $HOUT "<body>\n";
  if ($initials) {
    print $HOUT "
<p>
<a href='#A'>A</a> <a href='#B'>B</a> <a href='#C'>C</a> <a href='#D'>D</a>
<a href='#E'>E</a> <a href='#F'>F</a> <a href='#G'>G</a> <a href='#H'>H</a>
<a href='#I'>I</a> <a href='#J'>J</a> <a href='#K'>K</a> <a href='#L'>L</a>
<a href='#M'>M</a> <a href='#N'>N</a> <a href='#O'>O</a> <a href='#P'>P</a>
<a href='#Q'>Q</a> <a href='#R'>R</a> <a href='#S'>S</a> <a href='#T'>T</a>
<a href='#U'>U</a> <a href='#V'>V</a> <a href='#W'>W</a> <a href='#X'>X</a>
<a href='#Y'>Y</a> <a href='#Z'>Z</a>
";
  }
  if    ($htmlList) {  print $HOUT "<$htmlList>\n";  }
}


sub wrapTail {   # ($HOUT)
  my $HOUT = $_[0];
  if ($htmlList) {  print $HOUT "</$htmlList>\n";  }
  print $HOUT "<body>\n<html>\n";
}